Frocessing

(サンプル一覧を表示する)


[ライセンスの種類: LGPL]

Frocessing は高輪知明さん (nutsuさん) が作られた画像描画用ライブラリです。
Processing のような感覚で、描画処理を直感的に書くことができるようになっています。


・Frocessing (Spark Project)
http://www.libspark.org/wiki/nutsu/Frocessing

・Frocessing の asdoc
http://www.libspark.org/htdocs/as3/frocessing/

・特集:FrocessingではじめるActionScriptドローイング|gihyo.jp … 技術評論社
http://gihyo.jp/design/feature/01/frocessing


Flash の実行画面
Frocessing

Flashプレーヤーが入っていないか、JavaScriptが無効になっているようです。

Get Adobe Flash player

Frocessing
クリックすると画面がクリアされます。

ソースコード

package 
{
	import frocessing.display.F5MovieClip2DBmp;
	
	/**
	 * Frocessing のサンプル
	 * 高輪さんが書かれたサンプルをそのままお借りしています。
	 * 詳しくは技術評論社の連載ページを見てみてください。
	 * http://gihyo.jp/design/feature/01/frocessing
	 */
	public class Main extends F5MovieClip2DBmp 
	{
		/**
		 * 画面の横幅
		 */
		private var stage_width:Number  = 320;
		
		/**
		 * 画面の縦幅
		 */
		private var stage_height:Number = 240;
		
		/**
		 * 波線の分割数
		 */
		private var n:int = 5;
		
		/**
		 * ノイズの係数
		 */
		private var t:Number = 0;
		
		/**
		 * コンストラクタ
		 */
		public function Main():void 
		{
			super();
		}
		
		/**
		 * 初期化メソッド
		 * 初期化時に 1 度だけ呼ばれる。
		 */
		public function setup():void
		{
			size(stage_width, stage_height);
			background(0);
			noFill();
			stroke(255, 0.1);
		}
		
		/**
		 * 描画メソッド
		 * 毎フレーム呼ばれる。
		 */
		public function draw():void
		{
			// クリックされた時、画面をクリア
			if (isMousePressed) {
				background(0, 1);
			}

			translate(0, stage_height / 2);
			beginShape();
			curveVertex(-100, 0);
			
			for (var i:int = 0; i <= n; i++)
			{
				var xx:Number = i * stage_width / n;
				var yy:Number = noise(i * 0.25, t) * 200 - 100;
				curveVertex(xx, yy);
			}
			
			curveVertex(stage_width + 100, 0);
			endShape();
			t += 0.01;
		}
	}
}
		


FlashDevelop で外部ライブラリを使用するときは、 lib フォルダに SWC ファイルを追加した後、右クリックして "Add To Library" を選択してください。

ライブラリの設定 1


ライブラリ名が青くなったら、ビルド時に使用されるようになります。

ライブラリの設定 2