FlashVars の値を読み込む

(サンプル一覧を表示する)

FlashDevelop を使って、FlashVars の値を読み込むテストをしてみました。

FlashVars とは、プログラム開始時の引数のことで、
Flash では HTML ファイルの中に値をセットすることで、これを利用することができるようになります。

このサンプルでは、SwfObject という、
JavaScript で書かれた Flash 表示用ライブラリを使用して FlashVars の内容をセットしています。

具体的には次のような JavaScript コードで値を渡しています。

	var flashvars = {
		testString: "Test Message",
		testValue1: 123,
		testValue2: true
	};
実際どのような内容になっているかは、ブラウザからこのページのソースコードを見て確認してください。

FlashVars の値を読み込む

Flashプレーヤーが入っていないか、JavaScriptが無効になっているようです。

Get Adobe Flash player

FlashVars の値を読み込む

ソースコード

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	
	/**
	 * FlashVars の値を読み込むサンプル
	 * @author Hikipuro
	 */
	public class Main extends Sprite 
	{
		/**
		 * メッセージ表示用テキストフィールド
		 */
		private var textField:TextField;
		
		/**
		 * コンストラクタ
		 */
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		/**
		 * 初期化メソッド
		 * @param	e
		 */
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			
			// テキストフィールドの初期化
			textField = new TextField();
			textField.x = 5;
			textField.y = 5;
			textField.width = 310;
			textField.height = 230;
			textField.multiline = true;
			textField.wordWrap = true;
			addChild(textField);
			
			textField.text = "FlashVars のキーと値のリスト\n\n";

			// FlashVars の処理
			var vars:Object = loaderInfo.parameters;
			for (var key:String in vars)
			{
				// このループ内で if 文や switch 文を足して、
				// 一致するキーがあった場合に処理分けするようなコードを書いてください。
				var text:String = key + " = " + vars[key] + "\n";
				textField.appendText(text);
				//trace(text);
			}
		}
		
	}
	
}