ファイル名を指定してダウンロードする

(サンプル一覧を表示する)

FlashDevelop を使って、ファイル名を指定してダウンロードするテストをしてみました。

ダウンロードボタンを押すと、ファイル名を入力するダイアログボックスが表示されます。
保存ボタンを押すと、MP3 ファイルのダウンロードが開始されます。

曲は、フリー素材曲(MIDI/MP3)のダウンロードサイト / ハイパースペシャル さんからお借りしました。
Flash の実行画面
ファイル名を指定してダウンロードする

Flashプレーヤーが入っていないか、JavaScriptが無効になっているようです。

Get Adobe Flash player

ファイル名を指定してダウンロードする

ソースコード

package 
{
	import flash.display.CapsStyle;
	import flash.display.LineScaleMode;
	import flash.display.SimpleButton;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.events.ProgressEvent;
	import flash.net.FileReference;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	
	/**
	 * ファイル名を指定してダウンロードするサンプル
	 * @author Hikipuro
	 */
	public class Main extends Sprite 
	{
		/**
		 * 結果表示用テキストフィールド
		 */
		private var textField:TextField;
		
		/**
		 * ボタン
		 */
		private var button1:SimpleButton;
	
		/**
		 * ボタンのラベル
		 */
		private var buttonText1:TextField;
		
		/**
		 * ファイル参照オブジェクト
		 */
		private var fileReference:FileReference;
		
		/**
		 * コンストラクタ
		 */
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		/**
		 * 初期化メソッド
		 * @param	e
		 */
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			
			// 結果表示用テキストフィールド
			textField = new TextField();
			textField.autoSize = TextFieldAutoSize.CENTER;
			//textField.selectable = false;
			textField.x = 160;
			textField.y = 70;
			textField.text = "ボタンを押すと、曲のダウンロードを開始します。";
			addChild(textField);
			
			// ボタンのラベルの作成
			buttonText1 = new TextField();
			buttonText1.autoSize = TextFieldAutoSize.CENTER;
			buttonText1.selectable = false;
			buttonText1.x = 160;
			buttonText1.y = 110;
			buttonText1.text = "ダウンロード";
			addChild(buttonText1);
			
			// ボタンの作成
			button1 = new SimpleButton();
			button1.upState = makeRoundRect(0xDDDDDD, 100, 20, 10);
			button1.overState = makeRoundRect(0xFFFFFF, 100, 20, 10);
			button1.downState = makeRoundRect(0xBBBBBB, 100, 20, 10);
			button1.hitTestState = button1.upState;
			button1.addEventListener(MouseEvent.MOUSE_DOWN, onButtonMouseDown);
			button1.x = 110;
			button1.y = 110;
			addChild(button1);
		}

		/**
		 * ボタンが押された時のイベントハンドラ
		 * @param	event
		 */
		private function onButtonMouseDown(event:MouseEvent):void
		{
			var url:String = "http://hikipuro.is-a-geek.org/flash/game/sample/khs_come_cross_the_winter.mp3";
			var urlRequest:URLRequest = new URLRequest(url);
			fileReference = new FileReference();
			
			// イベントの登録
			fileReference.addEventListener(Event.OPEN, onOpen);
			fileReference.addEventListener(ProgressEvent.PROGRESS, onProgress);
			fileReference.addEventListener(Event.COMPLETE, onComplete);
			
			// ファイル選択ダイアログを表示して、ダウンロード開始する
			fileReference.download(urlRequest, "khs_come_cross_the_winter.mp3");
		}
		
		/**
		 * ダウンロード開始イベント
		 * @param	event
		 */
		private function onOpen(event:Event):void
		{
			// プログレスバーをクリアする
			graphics.clear();
			
			// 線の色と太さを決める
			graphics.lineStyle(10, 
							   0xff8888, 
							   1.0,
							   false, 
							   LineScaleMode.NORMAL, 
							   CapsStyle.NONE);
		}
		
		/**
		 * ダウンロード進行中イベント
		 * @param	event
		 */
		private function onProgress(event:ProgressEvent):void
		{
			// プログレスバーを描く
			var ratio:Number;
			ratio = event.bytesLoaded / event.bytesTotal;
			
			graphics.moveTo(10, 150);
			graphics.lineTo(10 + ratio * 300, 150);
			
			// テキストフィールドの更新
			textField.text = "ダウンロード中です。 : " + Math.floor(ratio * 100) + " %";
		}
		
		/**
		 * ダウンロード完了イベント
		 * @param	event
		 */
		private function onComplete(event:Event):void
		{
			textField.text = "ダウンロードが完了しました。";
		}
		
		/**
		 * 角丸の図形を描いたスプライトを作って返す
		 * @param	color	色
		 * @param	width	幅
		 * @param	height	高さ
		 * @param	round	角丸の大きさ
		 * @return	スプライト
		 */
		private function makeRoundRect(color:uint, width:int, height:int, round:int):Sprite
		{
			var s:Sprite = new Sprite();
			s.graphics.lineStyle(2);
			s.graphics.beginFill(color);
			s.graphics.drawRoundRect(0, 0, width, height, round);
			s.graphics.endFill();
			s.alpha = 0.3;
			return s;
		}
		
	}
	
}
		

このサンプルでは、IO Error イベントに対応する処理を書いていません。
実際にダウンロード処理を含んだ Flash を作る場合には、追加したほうが良いと思います。

外部リンク